alien attack 3k.prg ==0401==
    1 poke51,255:poke52,19:poke55,255:poke56,19:clr
    2 data0,0,0,8,8,8,8,8
    3 data24,24,24,24,24,60,60,60
    4 data0,0,0,16,16,16,16,16
    5 data9,11,15,15,31,63,0,0
    6 data144,208,240,240,248,252,0,0
    7 data126,255,255,255,255,153,24,0
    8 data0,0,0,0,24,24,24,24
    9 data24,24,24,24,24,24,60,60
   10 data24,25,31,31,31,24,24,24
   11 data126,255,255,255,255,60,24,24
   12 data24,152,248,248,248,24,24,24
   13 data0,0,24,126,255,255,66,0
   14 data0,24,24,24,24,24,0,0
   15 data0,12,28,60,56,48,0,0
   16 data1,144,4,80,2,88,0,33
   17 data0,0,76,16,72,48,180,64
   18 data128,2,64,8,0,64,4,0
   19 data200,129,0,8,0,2,97,0
   20 data24,24,24,24,24,24,24,24
   21 data0,0,0,0,0,0,0,0
   22 data0,0,0,0,24,24,24,24
   23 fori=0to512
   24 poke5120+i,peek(32768+i):nexti
   25 fori=0to167
   26 readx:poke5632+i,x:nexti
   27 poke36869,253:poke36879,110
   28 data0,0,0,24,24,24,24
   29 s$="{SHIFT-*}AB{down}{left}{left}{left}CED"
   30 print"{clr}":m$="     alien attack":p$="{wht}{home}{down}{down}{down}{down}{down}":gosub89
   31 m$="  written for vic-20":p$="{wht}{home}{down}{down}{down}{down}{down}{down}{down}":gosub89
   32 m$="     by a.e.webb":p$="{wht}{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}":gosub89
   33 m$="    instructions?":p$="{home}{wht}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}":gosub89
   34 geta$:ifa$=""then34
   35 ifa$="y"then94
   36 ti$="000000"
   37 dd=1:ss=7680:of=30720:sc=0
   38 sp=ss:print"{clr}"
   39 pokesp,32
   40 sp=sp+dd
   41 ifsp=7680thendd=1
   42 ifsp=7701thendd=-1
   43 de=300-sc*5:ifde<0thende=0
   44 ifti>deandfl=0then59
   45 pokesp,75:pokesp+of,1
   46 forxx=sp+22tosp+220step22
   47 ifpeek(xx)=65orpeek(xx)=71then71
   48 next
   49 geta$
   50 ifa$="_"andsp<>7680andsp<>7701thendd=-dd:goto39
   51 ifa$=" "andfl=0thenfl=1:q9=sp:bp=q9+22
   52 iffl=0then39
   53 pokebp,32
   54 bp=bp+22
   55 ifpeek(bp)<>32then62
   56 pokebp,76:pokebp+of,1
   57 ifbp<(q9+462)then39
   58 pokebp,32:fl=0:goto82
   59 s$="{SHIFT-*}AB{down}{left}{left}{left}CED"
   60 ifrnd(1)<.3thens$="TGF{down}{left}{left}{left}HIJ"
   61 pokeb,32:print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{wht}"tab(rnd(1)*20)s$:ti$="000000":goto39:rem bugfix (rms)
   62 ifpeek(bp)<>65andpeek(bp)<>71then67
   63 pokebp,78:pokebp-1,79:pokebp+1,80:pokebp+21,81:pokebp+22,82:pokebp+23,78:rem bugfix (rms)
   64 forll=1to20:next
   65 pokebp,32:pokebp-1,32:pokebp+1,32:pokebp+21,32:pokebp+22,32:pokebp+23,32
   66 fl=0:sc=sc+1:goto82
   67 ifpeek(bp)<>66andpeek(bp)<>70andpeek(bp)<>64andpeek(bp)<>84then70
   68 ifrnd(1)<.5thenpokebp-22,78:fl=0:goto82
   69 pokebp,78:pokebp+22,79:fl=0:goto82
   70 pokebp,32:forii=1to20:next:pokebp,rnd(1)*4+78:forii=1to50:next:fl=0:goto82
   71 forpp=xxtosp+22step-22
   72 pokepp,82:pokepp+of,1:next
   73 pokesp,81
   74 forpp=xx-22tosp+22step-22
   75 pokepp,32:next
   76 print"{home}{down}{down}{down}{down}you destroyed";sc
   77 poke198,0
   78 print"{down}{wht}press space for more"
   79 geta$:ifa$=""then79
   80 ifa$=" "thenpoke198,0:fl=0:goto36
   81 end
   82 de=300-sc*5:ifde<0thende=1
   83 fori=1toint(ti/de)
   84 s$="{SHIFT-*}AB{down}{left}{left}{left}CED"
   85 ifrnd(1)<.3thens$="TGF{down}{left}{left}{left}HIJ"
   86 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{wht}"tab(rnd(1)*20)s$
   87 next:ti$="000000"
   88 goto39
   89 o$="":ford=1tolen(m$)
   90 o$=right$(m$,d)+s$
   91 printp$;o$:forde=1to50:next
   92 o$=right$(m$,d)+"   {down}{left}{left}{left}   "
   93 printp$;o$:forde=1to50:next:next:return
   94 print"{clr}you pilot a space-ship.....K"
   95 print"{down}it moves constantly   across the top of the  screen."
   96 print"{down}the '_' key changes   the direction of the  ship."
   97 print"{down}aliens...{SHIFT-*}AB & FGF"
   98 print"         CED   HIJ"
   99 print"{down}move up the screen.   press the space bar tobomb them."
  100 print"{down}{down}press space for more"
  101 geti$:ifi$=""then101
  102 print"{clr}when they get near thetop they will shoot atyou if they get the   chance."
  103 print"{down}they never miss...."
  104 print"{down}a hit on the centre   of the alien destroys it..."
  105 print"{down}a hit to either side  of an alien might get through the protectiveshields"
  106 print"{down}and hit the alien but the alien will still  be lethal"
  107 print"{down}{down}press space for more"
  108 geti$:ifi$=""then108
  109 print"{clr}a bomb hitting the     shields will explode  leaving debris which will";
  110 print" detonate bombs   falling on the same   path."
  111 print"{down}{down}press space to start"
  112 geti$:ifi$=""then112
  113 goto36



;alien-attack-3k.txt ==ffff==